2011 год 1 тур

Требования

Крупная аптека ведет бухгалтерский учет в системе «1С:Предприятие 8». Лекарственные средства учитываются на счете 41 «Товары» в стоимостном и натуральном выражении. Аналитический учет на счете 41 ведется по товарам (лекарственным средствам). Сведения о товарной номенклатуре хранятся в справочнике «Товары». Для каждого товара в справочнике указан уникальный код лекарственного средства и наименование. Код имеет следующую структуру : xxx-yyy-zzz и представляет собой три трехзначных числа, отделяемых знаком «–». Лекарственные средства являются аналогами, если в их кодах совпадают средние три цифры. Например, лекарственные препараты с кодами 232-145-876 и 816-145-567 являются аналогами, поскольку у них совпадает средняя часть кода (145).

На основании данных информационной базы требуется сформировать отчет, в который необходимо включить пары лекарственных препаратов-аналогов, наиболее близких по цене. Если в базе имеются несколько пар аналогов с одинаковым разбросом цен, то в отчет надо включить более дешевые лекарственные средства, если среди них имеются несколько аналогов с одинаковыми ценами, то в отчет надо включить только один любой аналог.

Каркасная конфигурация

Задание необходимо выполнить в каркасной конфигурации, в которой имеется План счетов, содержащий счет 41, справочник «Товары», документ для ввода остатков товаров, при помощи которого введено несколько проводок по приходу товаров в дебет счета 41 и кредит условного счета 00.

ВНИМАНИЕ! Для отладки модуля отчета Вы можете добавлять в информационную базу каркасной конфигурации дополнительные товары и проводки. Жюри проводит тестирование на собственных данных, которые будут отличаться от данных, содержащихся в исходной информационной базе каркасной конфигурации.

Пример

Исходные данные

|  |  |  |  |  |
| --- | --- | --- | --- | --- |
| Код товара | Наименование | Остаток сумма | Остаток кол-во | Цена (расчет) |
| 111-222-333 | Изд-01 | 5000 | 5 | 1000.00 |
| 222-333-444 | Изд-02 | 15000 | 15 | 1000.00 |
| 111-555-222 | Изд-03 | 15000 | 5 | 3000.00 |
| 345-222-111 | Изд-04 | 25250 | 25 | 1010.00 |
| 321-555-003 | Изд-05 | 16500 | 5 | 3300.00 |
| 112-333-987 | Изд-06 | 5000 | 5 | 1000.00 |
| 345-222-765 | Изд-07 | 7105 | 7 | 1015.00 |
| 990-555-654 | Изд-08 | 5200 | 2 | 2600.00 |
| 990-555-658 | Изд-09 | 14000 | 5 | 2800.00 |

Итоговый отчет

**Лекарственные средства-аналоги**

|  |  |  |  |  |  |
| --- | --- | --- | --- | --- | --- |
| **Лекарственное средство** | | | **Аналог** | | |
| Код товара | Наименование | Цена | Код товара | Наименование | Цена |
| 345-222-111 | Изд-04 | 1010.00 | 345-222-765 | Изд-07 | 1015.00 |
| 222-333-444 | Изд-02 | 1000.00 | 112-333-987 | Изд-06 | 1000.00 |
| 990-555-654 | Изд-08 | 2600.00 | 990-555-658 | Изд-09 | 2800.00 |

Решение

Для получения пар аналогов с минимальной разницей в цене достаточно отсортировать все аналоги в порядке возрастанию цены (чтобы при одинаковой разнице в цене была взята первая пара – с меньшей ценой), далее обойти каждую группу аналогов, выбирая пару с минимальной разницей в цене. Рассмотрим пример (за исходные данные возьмем пример из требований):

Берем группы аналогов и сортируем их по возрастанию цены:

|  |  |  |
| --- | --- | --- |
| Группа | Товар | Цена |
| 555 | 990-555-654 | 2600 |
| 990-555-658 | 2800 |
| 111-555-222 | 3000 |
| 321-555-003 | 3300 |
| 333 | 222-333-444 | 1000 |
| 112-333-987 | 1000 |
| 222 | 111-222-333 | 1000 |
| 345-222-111 | 1010 |
| 345-222-765 | 1015 |

Обходим группы и определяем разницу в цене:

|  |  |  |  |
| --- | --- | --- | --- |
| Итерация | Товар 1 | Товар 2 | Разница |
| 1 | 990-555-658 | 990-555-654 | 200 |
| 2 | 111-555-222 | 990-555-658 | 200 |
| 3 | 321-555-003 | 111-555-222 | 300 |
| 4 | 222-333-444 | 112-333-987 | 0 |
| 5 | 345-222-111 | 111-222-333 | 10 |
| 6 | 345-222-765 | 345-222-111 | 5 |

После обхода сразу видны пары товаров с минимальной разницей в цене (если разница равна – берем ту пару, которая выше в пределах группы). Это пары:

|  |  |  |
| --- | --- | --- |
| Товар 1 | Товар 2 | Разница |
| 990-555-658 | 990-555-654 | 200 |
| 222-333-444 | 112-333-987 | 0 |
| 345-222-765 | 345-222-111 | 5 |

Реализация

Процедура КнопкаСформироватьНажатие(Кнопка)

ТабДок=ЭлементыФормы.ТабДок;

ТабДок.Очистить();

Макет=ПолучитьМакет("Макет");

Область=Макет.ПолучитьОбласть("Шапка");

ТабДок.Вывести(Область);

Запрос=Новый Запрос;

Запрос.Текст=

"ВЫБРАТЬ

| ЖурналПроводокОстатки.Субконто1 КАК Номенклатура,

| ЖурналПроводокОстатки.Субконто1.Код КАК Код,

| ЖурналПроводокОстатки.СуммаОстатокДт / ЖурналПроводокОстатки.КоличествоОстатокДт КАК Цена,

| ПОДСТРОКА(ЖурналПроводокОстатки.Субконто1.Код, 5, 3) КАК Артикул,

| 1 КАК КоличествоАртикулов

|ИЗ

| РегистрБухгалтерии.ЖурналПроводок.Остатки(&Дата, Счет = &Счет41, , ) КАК ЖурналПроводокОстатки

|

|УПОРЯДОЧИТЬ ПО

| ЖурналПроводокОстатки.Субконто1.Наименование";

Запрос.УстановитьПараметр("Дата",КонецДня(Дата));

Запрос.УстановитьПараметр("Счет41",ПланыСчетов.ПланСчетов.Товары);

ТабЗапроса=Запрос.Выполнить().Выгрузить();

ТабЗапроса.Колонки.Добавить("РазницаСоСледСтрокой");

ТабЗапроса.Сортировать("Цена");

ТабВрем=ТабЗапроса.Скопировать();

ТабВрем.Свернуть("Артикул","КоличествоАртикулов");

ТабВрем.Сортировать("Артикул");

Для Каждого ТекСтркоа из ТабВрем Цикл

Если ТекСтркоа.КоличествоАртикулов>1 Тогда

Отбор=Новый Структура;

Отбор.Вставить("Артикул", ТекСтркоа.Артикул);

товар1="";

товар2="";

СтрокиПоиска=ТабЗапроса.НайтиСтроки(Отбор);

МинРазница=строкиПоиска.Получить(0);

МинРазница=МинРазница.цена;

Для строк=0 По СтрокиПоиска.Количество()-2 цикл

строка = СтрокиПоиска.Получить(строк);

строка2= СтрокиПоиска.Получить(строк+1);

разница= строка.цена - строка2.цена;

строка.РазницаСоСледСтрокой = макс(разница,-разница);

если строка.РазницаСоСледСтрокой < МинРазница Тогда

МинРазница=строка.РазницаСоСледСтрокой;

НомТовар1=строк;

НомТовар2=строк+1;

конецЕсли;

КонецЦикла;

Товар1=СтрокиПоиска.Получить(НомТовар1);

Товар2=СтрокиПоиска.Получить(НомТовар2);

Область=Макет.ПолучитьОбласть("Строка");

Область.Параметры.Код = Товар1.Код;

Область.Параметры.Номенклатура = Товар1.Номенклатура;

Область.Параметры.Цена = Товар1.Цена;

Область.Параметры.Код2 = Товар2.Код;

Область.Параметры.Номенклатура2 = Товар2.Номенклатура;

Область.Параметры.Цена2 = Товар2.Цена;

ТабДок.Вывести(Область);

//сообщить (сокрлп(товар1)+" "+сокрлп(товар2));

КонецЕсли;

КонецЦикла;

ТабДок.ТолькоПросмотр=Истина;

КонецПроцедуры

Процедура ПередОткрытием(Отказ, СтандартнаяОбработка)

Дата=ТекущаяДата();

КонецПроцедуры

Решение с сайта <http://олимпиада1с.рф>

Пояснения к коду:

ТабДок=ЭлементыФормы.ТабДок;

ТабДок.Очистить();

Макет=ПолучитьМакет("Макет");

Область=Макет.ПолучитьОбласть("Шапка");

ТабДок.Вывести(Область);

В данном блоке получается элемент формы ТабличныйДокумент, для вывода результата. Идет отчистка табличного документа и получение макета, по которому будет строиться таблица результата. После этого – ввыводится шапка в табличный документ.

Запрос=Новый Запрос;

Запрос.Текст=

"ВЫБРАТЬ

| ЖурналПроводокОстатки.Субконто1 КАК Номенклатура,

| ЖурналПроводокОстатки.Субконто1.Код КАК Код,

| ЖурналПроводокОстатки.СуммаОстатокДт / ЖурналПроводокОстатки.КоличествоОстатокДт КАК Цена,

| ПОДСТРОКА(ЖурналПроводокОстатки.Субконто1.Код, 5, 3) КАК Артикул,

| 1 КАК КоличествоАртикулов

|ИЗ

| РегистрБухгалтерии.ЖурналПроводок.Остатки(&Дата, Счет = &Счет41, , ) КАК ЖурналПроводокОстатки

|

|УПОРЯДОЧИТЬ ПО

| ЖурналПроводокОстатки.Субконто1.Наименование";

Запрос.УстановитьПараметр("Дата",КонецДня(Дата));

Запрос.УстановитьПараметр("Счет41",ПланыСчетов.ПланСчетов.Товары);

ТабЗапроса=Запрос.Выполнить().Выгрузить();

ТабЗапроса.Колонки.Добавить("РазницаСоСледСтрокой");

ТабЗапроса.Сортировать("Цена");

В данном блоке генерируется запрос к базе данных. В запросе выбираются поля Номенклатура, Код номенклатуры, Цена (как средневзвешенная по остатками на указанную дату), Артикул (3 цифры посреди кода) и поле КоличествоАртиклов (изначально у всех равно 1), остатки берутся на указанную дату, из счета 41 и идет сортировка по наименованию номенклатуры. После указания текста запроса указываются параметры (Дата, как конец дня указанного в форме в поле Дата, Счет41 – план счетов Товары). Далее запрос выполняется и выгружается в таблицу значений ТабЗапроса. В неё добавляется колонка РазницаСоСледСтрокой, которая будет использоваться при расчетах. И сортируется по Цене.

ТабВрем=ТабЗапроса.Скопировать();

ТабВрем.Свернуть("Артикул","КоличествоАртикулов");

ТабВрем.Сортировать("Артикул");

В данном блоке таблица значений копируется в ТабВрем и группируется по полю Артикул, с указанием количества элементов в поле КоличествоАртикулов. После этого идет сортировка по полю Артикул.

Для Каждого ТекСтркоа из ТабВрем Цикл

Если ТекСтркоа.КоличествоАртикулов>1 Тогда

Отбор=Новый Структура;

Отбор.Вставить("Артикул", ТекСтркоа.Артикул);

товар1="";

товар2="";

СтрокиПоиска=ТабЗапроса.НайтиСтроки(Отбор);

МинРазница=строкиПоиска.Получить(0);

МинРазница=МинРазница.цена;

Для строк=0 По СтрокиПоиска.Количество()-2 цикл

строка = СтрокиПоиска.Получить(строк);

строка2= СтрокиПоиска.Получить(строк+1);

разница= строка.цена - строка2.цена;

строка.РазницаСоСледСтрокой = макс(разница,-разница);

если строка.РазницаСоСледСтрокой < МинРазница Тогда

МинРазница=строка.РазницаСоСледСтрокой;

НомТовар1=строк;

НомТовар2=строк+1;

конецЕсли;

КонецЦикла;

Товар1=СтрокиПоиска.Получить(НомТовар1);

Товар2=СтрокиПоиска.Получить(НомТовар2);

Область=Макет.ПолучитьОбласть("Строка");

Область.Параметры.Код = Товар1.Код;

Область.Параметры.Номенклатура = Товар1.Номенклатура;

Область.Параметры.Цена = Товар1.Цена;

Область.Параметры.Код2 = Товар2.Код;

Область.Параметры.Номенклатура2 = Товар2.Номенклатура;

Область.Параметры.Цена2 = Товар2.Цена;

ТабДок.Вывести(Область);

//сообщить (сокрлп(товар1)+" "+сокрлп(товар2));

КонецЕсли;

КонецЦикла;

В данном блоке идет обход групп артикулов. Если в группе больше одной записи (а значит есть 2 аналога), то из таблицы значений ТабЗапроса отбираются записи, соответствующие текущей группе и ищутся два товара с минимальной разницей в цене. Для этого обходятся все отобранные записи, сравниваются со следующей строкой и разницы сохраняется в поле РазницаСоСледСтрокой. Если разница меньше чем сохраненная разница записей, то данная пара запоминается, и её разница. После обхода отобранных записей найденная пара выводится в табличный документ результата.

ТабДок.ТолькоПросмотр=Истина;

Данная строка запрещает редактирование табличного документа с результатом.

Процедура ПередОткрытием(Отказ, СтандартнаяОбработка)

Дата=ТекущаяДата();

КонецПроцедуры

Данный блок используется для установки значения по умолчанию поля Дата на форме (выставляется текущая дата).

Сформированный отчет

